Bonchellon/sevtech-ages-1.12.2
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

minecraft server init

Browse Source
This commit is contained in:
Bonchellon
2025-07-23 08:37:00 +03:00
commit ccf1f5f4d0
2460 changed files with 291551 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

22
scripts/contenttweaker/fluids.zs Normal file
View File

@ -0,0 +1,22 @@
#loader contenttweaker
/*
SevTech: Ages ContentTweaker Fluids Script.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.contenttweaker.Color;
import mods.contenttweaker.Fluid;
import mods.contenttweaker.VanillaFactory;
var liquidSlime = VanillaFactory.createFluid("slime", Color.fromHex("3f5329"));
liquidSlime.vaporize = true;
liquidSlime.viscosity = 3000;
liquidSlime.register();
var liquidCheese = VanillaFactory.createFluid("cheese", Color.fromHex("FFE000"));
liquidCheese.density = 6000;
liquidCheese.viscosity = 1000;
liquidCheese.register();

53
scripts/contenttweaker/materials/init.zs Normal file
View File

@ -0,0 +1,53 @@
#loader contenttweaker
#priority 4000
/*
SevTech: Ages ContentTweaker Base Materials Script.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.contenttweaker.Color;
import mods.contenttweaker.Material;
import mods.contenttweaker.MaterialSystem;
static materials as Material[string] = {
"aquamarine": MaterialSystem.getMaterialBuilder().setName("Aquamarine").setColor(2009855).build(),
"ardite": MaterialSystem.getMaterialBuilder().setName("Ardite").setColor(Color.fromHex("d14210")).build(),
"bronze": MaterialSystem.getMaterialBuilder().setName("Bronze").setColor(13467442).build(),
"cobalt": MaterialSystem.getMaterialBuilder().setName("Cobalt").setColor(18347).build(),
"compressedIron": MaterialSystem.getMaterialBuilder().setName("Compressed Iron").setColor(8947848).build(),
"copper": MaterialSystem.getMaterialBuilder().setName("Copper").setColor(15766817).build(),
"coralium": MaterialSystem.getMaterialBuilder().setName("Coralium").setColor(Color.fromHex("358b95")).build(),
"diamond": MaterialSystem.getMaterialBuilder().setName("Diamond").setColor(9237730).build(),
"ender": MaterialSystem.getMaterialBuilder().setName("Ender Pearl").setColor(2869678).build(),
"enhancedGalgadorian": MaterialSystem.getMaterialBuilder().setName("Enhanced Galgadorian").setColor(9850751).build(),
"fiery": MaterialSystem.getMaterialBuilder().setName("Fiery").setColor(2891807).setHasEffect(true).build(),
"galgadorian": MaterialSystem.getMaterialBuilder().setName("Galgadorian").setColor(11625595).build(),
"glowstone": MaterialSystem.getMaterialBuilder().setName("Glowstone").setColor(16708616).build(),
"gold": MaterialSystem.getMaterialBuilder().setName("Gold").setColor(16776971).build(),
"inferium": MaterialSystem.getMaterialBuilder().setName("Inferium").setColor(Color.fromHex("718a00")).build(),
"invar": MaterialSystem.getMaterialBuilder().setName("Invar").setColor(9872012).build(),
"iron": MaterialSystem.getMaterialBuilder().setName("Iron").setColor(14211288).build(),
"lead": MaterialSystem.getMaterialBuilder().setName("Lead").setColor(5658219).build(),
"meteoricIron": MaterialSystem.getMaterialBuilder().setName("Meteoric Iron").setColor(Color.fromHex("aba398")).build(),
"modularium": MaterialSystem.getMaterialBuilder().setName("Modularium").setColor(16730368).build(),
"naphtha": MaterialSystem.getMaterialBuilder().setName("Naphtha").setColor(10703708).build(),
"osmium": MaterialSystem.getMaterialBuilder().setName("Osmium").setColor(Color.fromHex("aabbd2")).build(),
"plastic": MaterialSystem.getMaterialBuilder().setName("Plastic").setColor(16777215).build(),
"platinum": MaterialSystem.getMaterialBuilder().setName("Platinum").setColor(15066338).build(),
"propene": MaterialSystem.getMaterialBuilder().setName("Propene").setColor(8026746).build(),
"prosperity": MaterialSystem.getMaterialBuilder().setName("Prosperity").setColor(Color.fromHex("a5caca")).build(),
"redstone": MaterialSystem.getMaterialBuilder().setName("Redstone").setColor(9895936).build(),
"redstoneAlloy": MaterialSystem.getMaterialBuilder().setName("Redstone Alloy").setColor(15157577).build(),
"reinforcedMetal": MaterialSystem.getMaterialBuilder().setName("Reinforced Metal").setColor(7643841).build(),
"silicon": MaterialSystem.getMaterialBuilder().setName("Silicon").setColor(Color.fromHex("141414")).build(),
"silver": MaterialSystem.getMaterialBuilder().setName("Silver").setColor(15592941).build(),
"spacePlatinum": MaterialSystem.getMaterialBuilder().setName("Space Platinum").setColor(Color.fromHex("6e757b")).build(),
"steel": MaterialSystem.getMaterialBuilder().setName("Steel").setColor(4408907).build(),
"steeleaf": MaterialSystem.getMaterialBuilder().setName("Steeleaf").setColor(4283598394).build(),
"stone": MaterialSystem.getMaterialBuilder().setName("Stone").setColor(11117475).build(),
"titanium": MaterialSystem.getMaterialBuilder().setName("Titanium").setColor(Color.fromHex("1c232e")).build(),
"tin": MaterialSystem.getMaterialBuilder().setName("Tin").setColor(10275286).build()
};

117
scripts/contenttweaker/materials/largeScale.zs Normal file
View File

@ -0,0 +1,117 @@
#loader contenttweaker
/*
SevTech: Ages ContentTweaker Large Scale Script.
This script is intended for large scale registration.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.contenttweaker.Material;
import mods.contenttweaker.MaterialPartData;
import scripts.contenttweaker.materials.utils.addDefaultMoltenData;
import scripts.contenttweaker.materials.utils.addDefaultOreData;
import scripts.contenttweaker.materials.init.materials;
function init() {
// ==================================
// Add default parts for materials
var materailsForDefaultParts as Material[] = [
materials.bronze,
materials.cobalt,
materials.compressedIron,
materials.copper,
materials.enhancedGalgadorian,
materials.fiery,
materials.galgadorian,
materials.lead,
materials.modularium,
materials.reinforcedMetal,
materials.silver,
materials.steeleaf,
materials.tin
];
var defaultPartNames as string[] = [
"gear",
"plate",
"rod"
];
for i, metal in materailsForDefaultParts {
metal.registerParts(defaultPartNames);
}
// ==================================
// Apply Molten to Materials
var fluidMaterials as Material[] = [
materials.enhancedGalgadorian,
materials.galgadorian,
materials.invar,
materials.modularium,
materials.osmium,
materials.platinum,
materials.redstoneAlloy,
materials.reinforcedMetal,
materials.steeleaf
];
for i, fluid in fluidMaterials {
var fluidMaterialsData as MaterialPartData = fluid.registerPart("molten").getData();
addDefaultMoltenData(fluidMaterialsData);
}
// ==================================
// Custom gears to keep the same look
var gearMaterialList as Material[] = [
materials.diamond,
materials.gold,
materials.iron,
materials.steel
];
for material in gearMaterialList {
material.registerPart("gear");
}
// ==================================
// Ore Samples
var oreSampleMaterials as Material[] = [
materials.osmium,
materials.silicon
];
var oreSampleDrops as string[Material] = {
materials.osmium: "geolosys:cluster:12",
materials.silicon: "galacticraftcore:basic_item:2"
};
for material in oreSampleMaterials {
var sampleData as MaterialPartData = material.registerPart("ore_sample").getData();
sampleData.addDataValue("drops", oreSampleDrops[material]);
}
// ==================================
// Clusters
var clusters as Material[] = [
materials.titanium
];
for material in clusters {
material.registerPart("cluster");
}
// ==================================
// Dust
var dusts as Material[] = [
materials.ardite,
materials.cobalt
];
for material in dusts {
material.registerPart("dust");
}
}

147
scripts/contenttweaker/materials/misc.zs Normal file
View File

@ -0,0 +1,147 @@
#loader contenttweaker
/*
SevTech: Ages ContentTweaker Misc Script.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.contenttweaker.Material;
import mods.contenttweaker.MaterialPartData;
import scripts.contenttweaker.materials.utils.addDefaultMoltenData;
import scripts.contenttweaker.materials.utils.addDefaultOreData;
import scripts.contenttweaker.materials.init.materials;
function init() {
// Stone Nugget
materials.stone.registerPart("nugget");
// Aquamarine Ore
var oreAquamarineData = materials.aquamarine.registerPart("ore").getData();
addDefaultOreData(oreAquamarineData);
oreAquamarineData.addDataValue("drops", "astralsorcery:itemcraftingcomponent");
oreAquamarineData.addDataValue("harvestLevel", "1");
// Osmium Ore
// Use this over Mekanism's so we can give it the default behavior of Geolosys
var oreOsmiumData = materials.osmium.registerPart("ore").getData();
addDefaultOreData(oreOsmiumData);
oreOsmiumData.addDataValue("drops", "geolosys:cluster:12");
// Moon Iron Ore
var oreIronData = materials.iron.registerPart("ore").getData();
addDefaultOreData(oreIronData);
oreIronData.addDataValue("variants", "galacticraftcore:bottom");
oreIronData.addDataValue("drops", "geolosys:cluster");
// Mars Gold Ore
var oreGoldData = materials.gold.registerPart("ore").getData();
addDefaultOreData(oreGoldData);
oreGoldData.addDataValue("variants", "galacticraftplanets:bottom");
oreGoldData.addDataValue("drops", "geolosys:cluster:1");
// Kelper 22b Inferium Ore
var oreInferiumData = materials.inferium.registerPart("ore").getData();
addDefaultOreData(oreInferiumData);
oreInferiumData.addDataValue("variants", "extraplanets:kepler22b_stone");
oreInferiumData.addDataValue("drops", "mysticalagriculture:crafting");
// Kelper 22b Prosperity Ore
var oreProsperityData = materials.prosperity.registerPart("ore").getData();
addDefaultOreData(oreProsperityData);
oreProsperityData.addDataValue("variants", "extraplanets:kepler22b_stone");
oreProsperityData.addDataValue("drops", "mysticalagriculture:crafting:5");
// Liquid Ender Pearl
var fluidEnderData = materials.ender.registerPart("molten").getData();
addDefaultMoltenData(fluidEnderData);
// Liquid Titanium
var fluidTitaniumData = materials.titanium.registerPart("molten").getData();
fluidTitaniumData.addDataValue("density", "8000");
fluidTitaniumData.addDataValue("viscosity", "3000");
fluidTitaniumData.addDataValue("temperature", "1000");
fluidTitaniumData.addDataValue("vaporize", "false");
// Liquid Redstone
var fluidRedstoneData = materials.redstone.registerPart("molten").getData();
fluidRedstoneData.addDataValue("density", "8000");
fluidRedstoneData.addDataValue("viscosity", "3000");
fluidRedstoneData.addDataValue("temperature", "1000");
fluidRedstoneData.addDataValue("vaporize", "false");
// Liquid Glowstone
var fluidGlowstoneData = materials.glowstone.registerPart("molten").getData();
fluidGlowstoneData.addDataValue("density", "8000");
fluidGlowstoneData.addDataValue("viscosity", "3000");
fluidGlowstoneData.addDataValue("temperature", "1000");
fluidGlowstoneData.addDataValue("vaporize", "false");
// Naphtha
var fluidNaphthaData = materials.naphtha.registerPart("molten").getData();
fluidNaphthaData.addDataValue("density", "4000");
fluidNaphthaData.addDataValue("viscosity", "3000");
// Liquid Plastic
var fluidPlasticData = materials.plastic.registerPart("molten").getData();
fluidPlasticData.addDataValue("density", "4000");
fluidPlasticData.addDataValue("viscosity", "3000");
// Propene "Gas"
var fluidPropeneData = materials.propene.registerPart("molten").getData();
fluidPropeneData.addDataValue("density", "4000");
fluidPropeneData.addDataValue("viscosity", "3000");
// Redstone Alloy
var redstoneAlloyParts as string[] = [
"block",
"gear",
"ingot",
"plate",
"rod"
];
materials.redstoneAlloy.registerParts(redstoneAlloyParts);
// Platinum
var platinumParts as string[] = [
"block",
"dust",
"gear",
"ingot",
"plate",
"rod"
];
materials.platinum.registerParts(platinumParts);
// Invar
var invarParts as string[] = [
"block",
"gear",
"ingot",
"plate",
"rod"
];
materials.invar.registerParts(invarParts);
// Space Platinum
materials.spacePlatinum.registerPart("dust");
// Meteoric Iron
materials.meteoricIron.registerPart("dust");
// NOTE! Reduction = Footwear, Leggins, Chestplate, Headslot
// Copper Armor
var copperArmor = materials.copper.registerPart("armor").getData();
copperArmor.addDataValue("durability", "375");
copperArmor.addDataValue("reduction", "1,3,4,1");
copperArmor.addDataValue("toughness", "0");
// Bronze Armor
var bronzeArmor = materials.bronze.registerPart("armor").getData();
bronzeArmor.addDataValue("durability", "450");
bronzeArmor.addDataValue("reduction", "2,4,5,2");
bronzeArmor.addDataValue("toughness", "0");
}

26
scripts/contenttweaker/materials/utils.zs Normal file
View File

@ -0,0 +1,26 @@
#loader contenttweaker
#priority 4000
/*
SevTech: Ages ContentTweaker Utils Script.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.contenttweaker.MaterialPartData;
function addDefaultMoltenData(moltenData as MaterialPartData) {
moltenData.addDataValue("density", "4000");
moltenData.addDataValue("viscosity", "3000");
moltenData.addDataValue("temperature", "550");
moltenData.addDataValue("vaporize", "false");
}
function addDefaultOreData(oreData as MaterialPartData) {
oreData.addDataValue("variants", "minecraft:stone");
oreData.addDataValue("hardness", "5");
oreData.addDataValue("resistance", "15");
oreData.addDataValue("harvestTool", "pickaxe");
oreData.addDataValue("harvestLevel", "2");
}

14
scripts/contenttweaker/postInit.zs Normal file
View File

@ -0,0 +1,14 @@
#loader contenttweaker
#priority -100
/*
SevTech: Ages ContentTweaker Post Init Script.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
// ==================================
// Initialize Materials
scripts.contenttweaker.materials.largeScale.init();
scripts.contenttweaker.materials.misc.init();

17
scripts/contenttweaker/vanillaFactory.zs Normal file
View File

@ -0,0 +1,17 @@
#loader contenttweaker
/*
SevTech: Ages ContentTweaker Vanilla Factory Script.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.contenttweaker.VanillaFactory;
import mods.contenttweaker.Item;
var creeperTear as Item = VanillaFactory.createItem("creeper_tear");
creeperTear.register();
var theOj as Item = VanillaFactory.createItem("the_oj");
theOj.register();