minecraft server init

scripts/crafttweaker/classes/mods/abyssalcraft.zs

@@ -0,0 +1,90 @@
+#priority 3400
+
+/*
+	SevTech: Ages AbyssalCraft Script
+
+	This script is a zenClass to allow easy interation with AbyssalCraft.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IItemStack;
+
+import mods.abyssalcraft.Crystallizer;
+import mods.abyssalcraft.Materializer;
+import mods.abyssalcraft.Transmutator;
+import mods.abyssalcraft.RitualStages;
+
+zenClass AbyssalCraft {
+	var default_xp as float;
+
+	zenConstructor(defaultXP as float) {
+		default_xp = defaultXP;
+	}
+
+	/*
+		Remove a Transmutator Recipe
+	*/
+	function removeTransmutation(input as IItemStack) {
+		Transmutator.removeTransmutation(input);
+	}
+
+	/*
+		Add a Transmutator Recipe
+	*/
+	function addTransmutation(input as IItemStack, output as IItemStack) {
+		Transmutator.addTransmutation(input, output, default_xp);
+	}
+	function addTransmutation(input as IItemStack, output as IItemStack, exp as float) {
+		Transmutator.addTransmutation(input, output, exp as float);
+	}
+
+	/*
+		Remove a Crystallizer Recipe
+	*/
+	function removeCrystallization(input as IItemStack) {
+		Crystallizer.removeCrystallization(input);
+	}
+
+	/*
+		Add a Single Crystallizer Recipe
+	*/
+	function addSingleCrystallization(input as IItemStack, output as IItemStack) {
+		Crystallizer.addSingleCrystallization(input, output, default_xp);
+	}
+	function addSingleCrystallization(input as IItemStack, output as IItemStack, exp as float) {
+		Crystallizer.addSingleCrystallization(input, output, exp);
+	}
+
+	/*
+		Add a Dual Crystallizer Recipe
+	*/
+	function addCrystallization(input as IItemStack, output as IItemStack, output2 as IItemStack) {
+		Crystallizer.addCrystallization(input, output, output2, default_xp);
+	}
+	function addCrystallization(input as IItemStack, output as IItemStack, output2 as IItemStack, exp as float) {
+		Crystallizer.addCrystallization(input, output, output2, exp);
+	}
+
+	/*
+		Remove a Materializer Recipe
+	*/
+	function removeMaterialization(output as IItemStack) {
+		Materializer.removeMaterialization(output);
+	}
+
+	/*
+		Add a Materializer Recipe
+	*/
+	function addMaterialization(output as IItemStack, input as IItemStack[]) {
+		Materializer.addMaterialization(output, input);
+	}
+
+	/*
+		Add a Ritual to a Stage.
+	*/
+	function addRitualStage(stage as string, ritual as string) {
+		RitualStages.addRitualStage(stage, ritual);
+	}
+}

scripts/crafttweaker/classes/mods/actuallyAdditions.zs

@@ -0,0 +1,36 @@
+#priority 3400
+
+/*
+	SevTech: Ages Actually Additions Script
+
+	This script is a zenClass to allow easy interation with Actually Additions.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IItemStack;
+
+import mods.actuallyadditions.Crusher;
+
+zenClass ActuallyAdditions {
+	zenConstructor() {
+	}
+
+	/*
+		Remove a Crusher Recipe
+	*/
+	function removeCrusher(output as IItemStack) {
+		Crusher.removeRecipe(output);
+	}
+
+	/*
+		Add a Crusher Recipe
+	*/
+	function addCrusher(output as IItemStack, input as IItemStack) {
+		Crusher.addRecipe(output, input);
+	}
+	function addCrusher(output as IItemStack, input as IItemStack, outputSecondary as IItemStack, secondaryChance as int) {
+		Crusher.addRecipe(output, input, outputSecondary, secondaryChance);
+	}
+}

scripts/crafttweaker/classes/mods/appliedEnergistics.zs

@@ -0,0 +1,64 @@
+#priority 3400
+
+/*
+	SevTech: Ages Applied Energistics Script
+
+	This script is a zenClass to allow easy interation with Applied Energistics.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IItemStack;
+import crafttweaker.item.IIngredient;
+
+import mods.appliedenergistics2.Inscriber;
+import mods.appliedenergistics2.Grinder;
+
+zenClass AppliedEnergistics {
+	var default_spins as int;
+
+	zenConstructor(defaultSpins as int) {
+		default_spins = defaultSpins;
+	}
+
+	/*
+		Remove a Crusher Recipe
+	*/
+	function removeGrindstone(input as IItemStack) {
+		Grinder.removeRecipe(input);
+	}
+
+	/*
+		Add a Crusher Recipe
+	*/
+	function addGrindstone(output as IItemStack, input as IItemStack) {
+		Grinder.addRecipe(output, input, default_spins);
+	}
+	function addGrindstone(output as IItemStack, input as IItemStack, spins as int) {
+		Grinder.addRecipe(output, input, spins);
+	}
+	function addGrindstone(output as IItemStack, input as IItemStack, spins as int, outputSecondary as IItemStack, secondaryChance as int) {
+		Grinder.addRecipe(output, input, spins, outputSecondary, secondaryChance);
+	}
+
+	/*
+		Remove an Inscriber Recipe.
+	*/
+	function removeInscribe(output as IItemStack) {
+		Inscriber.removeRecipe(output);
+	}
+
+	/*
+		Add an Inscriber Recipe.
+	*/
+	function addInscribe(output as IItemStack, input as IIngredient, inscribe as bool) {
+		Inscriber.addRecipe(output, input, inscribe);
+	}
+	function addInscribe(output as IItemStack, input as IIngredient, inscribe as bool, top as IIngredient) {
+		Inscriber.addRecipe(output, input, inscribe, top);
+	}
+	function addInscribe(output as IItemStack, input as IIngredient, inscribe as bool, top as IIngredient, bottom as IIngredient) {
+		Inscriber.addRecipe(output, input, inscribe, top, bottom);
+	}
+}

scripts/crafttweaker/classes/mods/armoreablemobs.zs

@@ -0,0 +1,86 @@
+#priority 3400
+
+/*
+	SevTech: Ages Armoreable Mobs Script
+
+	This script is a zenClass to allow easy interation with Armoreable Mobs.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import mods.armoreablemobs.ArmorHandler;
+import mods.armoreablemobs.ArmorEntity;
+import mods.armoreablemobs.ArmorSlot;
+import mods.armoreablemobs.ArmorGroup;
+
+zenClass ArmoreableMobs {
+	var mobEntities as ArmorEntity[string][string] = {};
+
+	var defaultArmorDropChance as double = 0.15;
+	var blankGroup as ArmorGroup = ArmorHandler.createArmorGroup("Blank", 1.0);
+
+	zenConstructor() {
+		// Set up "Blank" group
+		blankGroup.addArmor(ArmorHandler.createArmorSlot("head", null, 1, 0));
+		blankGroup.addArmor(ArmorHandler.createArmorSlot("chest", null, 1, 0));
+		blankGroup.addArmor(ArmorHandler.createArmorSlot("legs", null, 1, 0));
+		blankGroup.addArmor(ArmorHandler.createArmorSlot("feet", null, 1, 0));
+		blankGroup.addArmor(ArmorHandler.createArmorSlot("mainhand", null, 1, 0));
+		blankGroup.addArmor(ArmorHandler.createArmorSlot("offhand", null, 1, 0));
+	}
+
+	function addMobEntity(mobEntityType as string, mobName as string) {
+		var mobEntityTypeExists as bool = (mobEntities has mobEntityType);
+
+		if (mobEntityTypeExists) {
+			if (mobEntities[mobEntityType] has mobName) {
+				logger.logWarning("Attempted to add " ~ mobName
+					~ " as a mob armor entity but already exists in " ~ mobEntityType ~ " type");
+				return null;
+			}
+		}
+
+		if (!mobEntityTypeExists) {
+			mobEntities[mobEntityType] = {};
+		}
+
+		mobEntities[mobEntityType][mobName] = ArmorHandler.createArmorEntity(mobName);
+	}
+
+	function addMobEntities(mobEntityType as string, mobNames as string[]) {
+		for mobName in mobNames {
+			addMobEntity(mobEntityType, mobName);
+		}
+	}
+
+	/**
+	 * Clears all gear from the mobs added to mobEntities
+	 */
+	function clearAllMobGear() {
+		for mobEntityType, mobEntitiesForType in mobEntities {
+			for mobName, mobEntity in mobEntitiesForType {
+				blankGroup.addEntity(mobEntity);
+			}
+		}
+	}
+
+	/**
+	 * Adds armor group to the specified armor type
+	 */
+	function addArmorGroupToType(mobEntityType as string, armorGroup as ArmorGroup) {
+		if (!(mobEntities has mobEntityType)) {
+			logger.logWarning("Attempted to add armor group to " ~ mobEntityType ~ " mobs but none exist");
+		}
+
+		for mobName, mobEntity in mobEntities[mobEntityType] {
+			armorGroup.addEntity(mobEntity);
+		}
+	}
+
+	function addArmorGroupsToType(mobEntityType as string, armorGroups as ArmorGroup[]) {
+		for armorGroup in armorGroups {
+			addArmorGroupToType(mobEntityType, armorGroup);
+		}
+	}
+}

scripts/crafttweaker/classes/mods/astralSorcery.zs

@@ -0,0 +1,49 @@
+#priority 3400
+
+/*
+	SevTech: Ages Astral Sorcery Script
+
+	This script is a zenClass to allow easy interation with Astral Sorcery.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IItemStack;
+
+import mods.astralsorcery.Grindstone;
+import mods.astralsorcery.StarlightInfusion;
+
+zenClass AstralSorcery {
+	zenConstructor() {
+	}
+
+	/*
+		Remove a Grindstone Recipe
+	*/
+	function removeGrindstone(output as IItemStack) {
+		Grindstone.removeRecipe(output);
+	}
+
+	/*
+		Add a Grindstone Recipe
+	*/
+	function addGrindstone(input as IItemStack, output as IItemStack) {
+		Grindstone.addRecipe(input, output);
+	}
+
+	/*
+		Remove a Starlight Infusion Recipe
+	*/
+	function removeStarlight(output as IItemStack) {
+		StarlightInfusion.removeInfusion(output);
+	}
+
+	/*
+		Add a Starlight Infusion Recipe
+	*/
+	function addStarlight(input as IItemStack, output as IItemStack, consumeMultiple as bool, consumptionChance as float, tickTime as int) {
+		StarlightInfusion.addInfusion(input, output, consumeMultiple, consumptionChance, tickTime);
+	}
+}
+

scripts/crafttweaker/classes/mods/betterwithmods.zs

@@ -0,0 +1,104 @@
+#priority 3400
+
+/*
+	SevTech: Ages Better With Mods/Addons Script
+
+	This script is a zenClass to allow easy interation with Better With Mods/Addons.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IIngredient;
+import crafttweaker.item.IItemStack;
+
+import mods.betterwithaddons.DryingBox;
+import mods.betterwithaddons.SoakingBox;
+import mods.betterwithaddons.Spindle;
+import mods.betterwithmods.Cauldron;
+import mods.betterwithmods.Crucible;
+import mods.betterwithmods.Kiln;
+import mods.betterwithmods.Mill;
+import mods.betterwithmods.Saw;
+
+zenClass BetterWithMods {
+	zenConstructor() {
+	}
+
+	/*
+		Remove a Kiln recipe
+	*/
+	function removeKiln(input as IItemStack) {
+		Kiln.remove(input);
+	}
+
+	/*
+		Remove a Soaking recipe
+	*/
+	function removeSoaking(input as IItemStack) {
+		SoakingBox.remove(input);
+	}
+
+	/*
+		Remove a Saw recipe
+	*/
+	function removeSaw(outputs as IItemStack[]) {
+		Saw.remove(outputs);
+	}
+
+	/*
+		Remove a Crucible recipe
+	*/
+	function removeCrucible(outputs as IItemStack[]) {
+		Crucible.remove(outputs);
+	}
+
+	/*
+		Remove a Spindle recipe
+	*/
+	function addSpindle(outputs as IItemStack[], input as IIngredient, consumesSpindle as bool) {
+		Spindle.add(outputs, input, consumesSpindle);
+	}
+
+	/*
+		Add a Mill recipe.
+	*/
+	function addMilling(inputs as IIngredient[], outputs as IItemStack[]) {
+		Mill.addRecipe(inputs, outputs);
+	}
+
+	/*
+		Remove a Mill recipe.
+	*/
+	function removeMilling(outputs as IItemStack[]) {
+		Mill.remove(outputs);
+	}
+
+	/*
+		Add a Cauldron recipe.
+	*/
+	function addCauldron(inputs as IIngredient[], outputs as IItemStack[]) {
+		addCauldron(inputs, outputs, false);
+	}
+	function addCauldron(inputs as IIngredient[], outputs as IItemStack[], stoked as bool) {
+		if (stoked) {
+			Cauldron.addStoked(inputs, outputs);
+		} else {
+			Cauldron.addUnstoked(inputs, outputs);
+		}
+	}
+
+	/*
+		Remove a Cauldron recipe.
+	*/
+	function removeCauldron(outputs as IItemStack[]) {
+		Cauldron.remove(outputs);
+	}
+
+	/*
+		Remove a Drying Box recipe.
+	*/
+	function removeDrying(input as IItemStack) {
+		DryingBox.remove(input);
+	}
+}

scripts/crafttweaker/classes/mods/bloodMagic.zs

@@ -0,0 +1,76 @@
+#priority 3400
+
+/*
+	SevTech: Ages Blood Magic Script
+
+	This script is a zenClass to allow easy interation with Blood Magic.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IItemStack;
+import crafttweaker.item.IIngredient;
+
+import mods.bloodmagic.AlchemyArray;
+import mods.bloodmagic.AlchemyTable;
+import mods.bloodmagic.BloodAltar;
+
+zenClass BloodMagic {
+	zenConstructor() {
+	}
+
+	/*
+		Remove a Alchemy Table Recipe
+
+		http://crafttweaker.readthedocs.io/en/latest/#Mods/Modtweaker/BloodMagic/AlchemyTable/#removal
+	*/
+	function removeAlchemyTable(inputs as IItemStack[]) {
+		AlchemyTable.removeRecipe(inputs);
+	}
+
+	/*
+		Add a Alchemy Table Recipe
+
+		http://crafttweaker.readthedocs.io/en/latest/#Mods/Modtweaker/BloodMagic/AlchemyTable/#addition
+	*/
+	function addAlchemyTable(output as IItemStack, inputs as IIngredient[], syphon as int, tickTime as int, minTier as int) {
+		AlchemyTable.addRecipe(output, inputs, syphon, tickTime, minTier);
+	}
+
+	/*
+		Remove a Alchemy Table Recipe
+
+		http://crafttweaker.readthedocs.io/en/latest/#Mods/Modtweaker/BloodMagic/AlchemyArray/#removal
+	*/
+	function removeAlchemyArray(input as IItemStack, catalyst as IItemStack) {
+		AlchemyArray.removeRecipe(input, catalyst);
+	}
+
+	/*
+		Add a Alchemy Array Recipe
+
+		http://crafttweaker.readthedocs.io/en/latest/#Mods/Modtweaker/BloodMagic/AlchemyArray/#addition
+	*/
+	function addAlchemyArray(input as IItemStack, catalyst as IItemStack, output as IItemStack) {
+		AlchemyArray.addRecipe(input, catalyst, output);
+	}
+
+	/*
+		Remove a Blood Altar Recipe
+
+		http://crafttweaker.readthedocs.io/en/latest/#Mods/Modtweaker/BloodMagic/BloodAltar/#removal
+	*/
+	function removeAltar(input as IItemStack) {
+		BloodAltar.removeRecipe(input);
+	}
+
+	/*
+		Add a Blood Altar Recipe
+
+		http://crafttweaker.readthedocs.io/en/latest/#Mods/Modtweaker/BloodMagic/BloodAltar/#addition
+	*/
+	function addAltar(output as IItemStack, input as IItemStack, minimumTier as int, syphon as int, consumeRate as int, drainRate as int) {
+		BloodAltar.addRecipe(output, input, minimumTier, syphon, consumeRate, drainRate);
+	}
+}

scripts/crafttweaker/classes/mods/horsePower.zs

@@ -0,0 +1,68 @@
+#priority 3400
+
+/*
+	SevTech: Ages Horse Power Script
+
+	This script is a zenClass to allow easy interation with Horse Power.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IIngredient;
+import crafttweaker.item.IItemStack;
+
+import mods.horsepower.ChoppingBlock;
+import mods.horsepower.Grindstone;
+import mods.horsepower.Press;
+import mods.horsepower.Recipes;
+
+zenClass HorsePower {
+	var def_chop as int;
+	var def_grind as int;
+
+	zenConstructor(defChop as int, defGrind as int) {
+		def_chop = defChop;
+		def_grind = defGrind;
+	}
+
+	/*
+		Add a Chopping Block recipe.
+
+		By default if not set recipes would be set to manual only.
+	*/
+	function addChopping(output as IItemStack, input as IIngredient) {
+		addChopping(output, input, def_chop, true);
+	}
+	function addChopping(output as IItemStack, input as IIngredient, time as int) {
+		addChopping(output, input, time, true);
+	}
+	function addChopping(output as IItemStack, input as IIngredient, time as int, manual as bool) {
+		ChoppingBlock.add(input, output, time, manual);
+	}
+
+	/*
+		Add a Grindstone recipe.
+
+		By default if not set recipes would be set to manual only.
+	*/
+	function addGrindstone(output as IItemStack, input as IIngredient) {
+		addGrindstone(output, input, def_grind, true);
+	}
+	function addGrindstone(output as IItemStack, input as IIngredient, secondaryOutput as IItemStack, secondaryChance as int) {
+		addGrindstone(output, input, def_grind, true, secondaryOutput, secondaryChance);
+	}
+	function addGrindstone(output as IItemStack, input as IIngredient, time as int, hand as bool) {
+		Grindstone.add(input, output, time, hand);
+	}
+	function addGrindstone(output as IItemStack, input as IIngredient, time as int, hand as bool, secondaryOutput as IItemStack, secondaryChance as int) {
+		Grindstone.add(input, output, time, hand, secondaryOutput, secondaryChance);
+	}
+
+	/*
+		Add a Press recipe.
+	*/
+	function addPress(input as IIngredient, output as IItemStack) {
+		Press.add(input, output);
+	}
+}

scripts/crafttweaker/classes/mods/immersiveEngineering.zs

@@ -0,0 +1,109 @@
+#priority 3400
+
+/*
+	SevTech: Ages Immersive Engineering Script
+
+	This script is a zenClass to allow easy interation with Immersive Engineering.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IItemStack;
+import crafttweaker.item.IIngredient;
+
+import mods.immersiveengineering.AlloySmelter;
+import mods.immersiveengineering.ArcFurnace;
+import mods.immersiveengineering.Crusher;
+import mods.immersiveengineering.MetalPress;
+
+zenClass ImmersiveEngineering {
+	var default_energy as int;
+	var default_alloy as int;
+
+	zenConstructor(defaultEnergy as int, defaultAlloy as int) {
+		default_energy = defaultEnergy;
+		default_alloy = defaultAlloy;
+	}
+
+	/*
+		Remove a Crusher Recipe by Output. (Default)
+	*/
+	function removeCrusher(output as IItemStack) {
+		Crusher.removeRecipe(output);
+	}
+
+	/*
+		Remove a Crusher Recipe by Input.
+	*/
+	function removeCrusherByInput(input as IItemStack) {
+		Crusher.removeRecipesForInput(input);
+	}
+
+	/*
+		Add a Crusher Recipe
+	*/
+	function addCrusher(output as IItemStack, input as IIngredient) {
+		Crusher.addRecipe(output, input, default_energy);
+	}
+	function addCrusher(output as IItemStack, input as IIngredient, energy as int) {
+		Crusher.addRecipe(output, input, energy);
+	}
+	function addCrusher(output as IItemStack, input as IIngredient, secondaryOutput as IItemStack, secondaryChance as double) {
+		Crusher.addRecipe(output, input, default_energy, secondaryOutput, secondaryChance);
+	}
+	function addCrusher(output as IItemStack, input as IIngredient, energy as int, secondaryOutput as IItemStack, secondaryChance as double) {
+		Crusher.addRecipe(output, input, energy, secondaryOutput, secondaryChance);
+	}
+
+	/*
+		Remove an Alloy Smelter Recipe
+	*/
+	function removeAlloy(output as IItemStack) {
+		AlloySmelter.removeRecipe(output);
+	}
+
+	/*
+		Add an Alloy Smelter Recipe
+	*/
+	function addAlloy(output as IItemStack, input as IIngredient, input2 as IIngredient) {
+		AlloySmelter.addRecipe(output, input, input2, default_alloy);
+	}
+	function addAlloy(output as IItemStack, input as IIngredient, input2 as IIngredient, time as int) {
+		AlloySmelter.addRecipe(output, input, input2, time);
+	}
+
+	/*
+		Remove an Arc Furnace Recipe
+	*/
+	function removeArcFurn(output as IItemStack) {
+		ArcFurnace.removeRecipe(output);
+	}
+
+	/*
+		Add a Arc Furnace Recipe
+	*/
+	function addArcFurn(output as IItemStack, input as IIngredient, slag as IItemStack, time as int, energy as int) {
+		ArcFurnace.addRecipe(output, input, slag, time, energy);
+	}
+	function addArcFurn(output as IItemStack, input as IIngredient, slag as IItemStack, time as int, energy as int, additives as IIngredient[]) {
+		ArcFurnace.addRecipe(output, input, slag, time, energy, additives);
+	}
+
+	/*
+		Remove a Metal Press Recipe
+	*/
+	function removePress(output as IItemStack) {
+		MetalPress.removeRecipe(output);
+	}
+
+	/*
+		Add a Metal Press Recipe
+	*/
+	function addPress(output as IItemStack, input as IIngredient, mold as IItemStack, inputSize as int) {
+		MetalPress.addRecipe(output, input, mold, 500, inputSize);
+	}
+	function addPress(output as IItemStack, input as IIngredient, mold as IItemStack, energy as int, inputSize as int) {
+		MetalPress.addRecipe(output, input, mold, energy, inputSize);
+	}
+}

scripts/crafttweaker/classes/mods/mekanism.zs

@@ -0,0 +1,234 @@
+#priority 3400
+
+/*
+	SevTech: Ages Mekanism Script
+
+	This script is a zenClass to allow easy interation with Mekanism.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IIngredient;
+import crafttweaker.item.IItemStack;
+import crafttweaker.liquid.ILiquidStack;
+
+import mod.mekanism.gas.IGasStack;
+
+import mods.mekanism.chemical.crystallizer as Crystallizer;
+import mods.mekanism.chemical.injection as Injection;
+import mods.mekanism.combiner as Combiner;
+import mods.mekanism.compressor as Compressor;
+import mods.mekanism.crusher as Crusher;
+import mods.mekanism.enrichment as Enrichment;
+import mods.mekanism.infuser as Infuser;
+import mods.mekanism.purification as PurificationChamber;
+import mods.mekanism.reaction as PressurisedReactionChamber;
+import mods.mekanism.sawmill as Sawmill;
+import mods.mekanism.smelter as Smelter;
+
+zenClass Mekanism {
+	zenConstructor() {
+	}
+
+	/*
+		Remove a Enrichment Chamber Recipe
+	*/
+	function removeEnrichment(input as IIngredient) {
+		Enrichment.removeRecipe(input);
+	}
+	function removeEnrichment(input as IIngredient, output as IIngredient) {
+		Enrichment.removeRecipe(input, output);
+	}
+
+	/*
+		Add a Enrichment Chamber Recipe
+	*/
+	function addEnrichment(input as IIngredient, output as IItemStack) {
+		Enrichment.addRecipe(input, output);
+	}
+
+	/*
+		Add a Chemical Injection Chamber Recipe
+	*/
+	function addChemicalInjection(input as IIngredient, gasInput as IGasStack, output as IItemStack) {
+		Injection.addRecipe(input, gasInput, output);
+	}
+
+	/*
+		Remove a Chemical Injection Chamber Recipe
+	*/
+	function removeChemicalInjection(output as IIngredient) {
+		Injection.removeRecipe(output);
+	}
+
+	/*
+		Add a Combiner Recipe
+	*/
+	function addCombiner(input as IIngredient, extraInput as IIngredient, output as IItemStack) {
+		Combiner.addRecipe(input, extraInput, output);
+	}
+
+	/*
+		Remove a Combiner Recipe
+	*/
+	function removeCombiner(output as IIngredient) {
+		Combiner.removeRecipe(output);
+	}
+	function removeCombiner(output as IIngredient, input as IIngredient) {
+		Combiner.removeRecipe(output, input);
+	}
+	function removeCombiner(output as IIngredient, input as IIngredient, extra as IIngredient) {
+		Combiner.removeRecipe(output, input, extra);
+	}
+
+	/*
+		Add a Crusher Recipe
+	*/
+	function addCrusher(input as IIngredient, output as IItemStack) {
+		Crusher.addRecipe(input, output);
+	}
+
+	/*
+		Remove a Crusher Recipe
+	*/
+	function removeCrusher(output as IIngredient) {
+		Crusher.removeRecipe(output);
+	}
+	function removeCrusher(output as IIngredient, input as IIngredient) {
+		Crusher.removeRecipe(output, input);
+	}
+
+	/*
+		Add an Infuser Recipe
+	*/
+	function addInfusion(infusionType as string, toConsume as int, input as IIngredient, output as IItemStack) {
+		Infuser.addRecipe(infusionType, toConsume, input, output);
+	}
+
+	/*
+		Remove an Infuser Recipe
+	*/
+	function removeInfusion(output as IIngredient) {
+		Infuser.removeRecipe(output);
+	}
+	function removeInfusion(output as IIngredient, input as IIngredient, infusionType as string) {
+		Infuser.removeRecipe(output, input, infusionType);
+	}
+
+	/*
+		Add a Chemical Crystallizer Recipe
+	*/
+	function addChemicalCrystallizer(inputGas as IGasStack, output as IItemStack) {
+		Crystallizer.addRecipe(inputGas, output);
+	}
+
+	/*
+		Remove a Chemical Crystallizer Recipe
+	*/
+	function removeChemicalCrystallizer(output as IIngredient) {
+		Crystallizer.removeRecipe(output);
+	}
+	function removeChemicalCrystallizer(output as IIngredient, inputGas as IIngredient) {
+		Crystallizer.removeRecipe(output, inputGas);
+	}
+
+	/*
+		Add an Energized Smelter Recipe
+	*/
+	function addSmelter(input as IIngredient, output as IItemStack) {
+		Smelter.addRecipe(input, output);
+	}
+
+	/*
+		Remove an Energized Smelter Recipe
+	*/
+	function removeSmelter(input as IIngredient) {
+		Smelter.removeRecipe(input);
+	}
+	function removeSmelter(input as IIngredient, output as IIngredient) {
+		Smelter.removeRecipe(input, output);
+	}
+
+	/*
+		Add an Osmium Compressor Recipe
+	*/
+	function addCompressor(input as IIngredient, output as IItemStack) {
+		Compressor.addRecipe(input, output);
+	}
+	function addCompressor(input as IIngredient, inputGas as IGasStack, output as IItemStack) {
+		Compressor.addRecipe(input, inputGas, output);
+	}
+
+	/*
+		Remove an Osmium Compressor Recipe
+	*/
+	function removeCompressor(output as IItemStack) {
+		Compressor.removeRecipe(output);
+	}
+	function removeCompressor(output as IItemStack, input as IIngredient, inputGas as IIngredient) {
+		Compressor.removeRecipe(output, input, inputGas);
+	}
+
+	/*
+		Add a Sawmill Recipe
+	*/
+	function addSawmill(input as IIngredient, output as IItemStack) {
+		Sawmill.addRecipe(input, output);
+	}
+	function addSawmill(input as IIngredient, output as IItemStack, bonusOutput as IItemStack, bonusChance as double) {
+		Sawmill.addRecipe(input, output, bonusOutput, bonusChance);
+	}
+
+	/*
+		Remove a Sawmill Recipe
+	*/
+	function removeSawmill(input as IIngredient) {
+		Sawmill.removeRecipe(input);
+	}
+	function removeSawmill(input as IIngredient, output as IIngredient) {
+		Sawmill.removeRecipe(input, output);
+	}
+	function removeSawmill(input as IIngredient, output as IIngredient, bonusOutput as IIngredient) {
+		Sawmill.removeRecipe(input, output, bonusOutput);
+	}
+
+	/*
+		Add a Purification Chamber Recipe
+	*/
+	function addPurification(input as IIngredient, output as IItemStack) {
+		PurificationChamber.addRecipe(input, output);
+	}
+	function addPurification(input as IIngredient, inputGas as IGasStack, output as IItemStack) {
+		PurificationChamber.addRecipe(input, inputGas, output);
+	}
+
+	/*
+		Remove a Purification Chamber Recipe
+	*/
+	function removePurification(output as IItemStack) {
+		PurificationChamber.removeRecipe(output);
+	}
+	function removePurification(output as IItemStack, input as IIngredient, inputGas as IIngredient) {
+		PurificationChamber.removeRecipe(output, input, inputGas);
+	}
+
+	/*
+		Add a Pressurised Reaction Chamber Recipe
+
+		An energy value of 0.0 uses a default value in Mekanism
+	*/
+	function addPRC(itemInput as IIngredient, liquidInput as ILiquidStack, gasInput as IGasStack, itemOutput as IItemStack, gasOutput as IGasStack, energy as double, duration as int) {
+		PressurisedReactionChamber.addRecipe(itemInput, liquidInput, gasInput, itemOutput, gasOutput, energy, duration);
+	}
+
+	/*
+		Remove a Pressurised Reaction Chamber Recipe
+	*/
+	function removePRC(itemOutput as IIngredient, gasOutput as IGasStack) {
+		PressurisedReactionChamber.removeRecipe(itemOutput, gasOutput);
+	}
+	function removePRC(itemOutput as IIngredient, gasOutput as IGasStack, itemInput as IIngredient, liquidInput as ILiquidStack, gasInput as IGasStack) {
+		PressurisedReactionChamber.removeRecipe(itemOutput, gasOutput, itemInput, liquidInput, gasInput);
+	}
+}

scripts/crafttweaker/classes/mods/tinkers.zs

@@ -0,0 +1,125 @@
+#priority 3400
+
+/*
+	SevTech: Ages Tinkers Construct Script
+
+	This script is a zenClass to allow easy interation with Tinkers Construct.
+
+	Note: These scripts are created and for the usage in SevTech: Ages and other
+	modpacks curated by DarkPacks. You can use these scripts for reference and for
+	learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.entity.IEntityDefinition;
+import crafttweaker.item.IIngredient;
+import crafttweaker.item.IItemStack;
+import crafttweaker.liquid.ILiquidStack;
+
+import mods.tconstruct.Alloy;
+import mods.tconstruct.Casting;
+import mods.tconstruct.Drying;
+import mods.tconstruct.Melting;
+
+zenClass Tinkers {
+	zenConstructor() {
+	}
+
+	/*
+		Add an Alloying recipe.
+	*/
+	function addAlloying(output as ILiquidStack, inputs as ILiquidStack[]) {
+		Alloy.addRecipe(output, inputs);
+	}
+
+	/*
+		Remove an Alloying recipe.
+	*/
+	function removeAlloying(output as ILiquidStack) {
+		Alloy.removeRecipe(output);
+	}
+	function removeAlloying(output as ILiquidStack, inputs as ILiquidStack[]) {
+		Alloy.removeRecipe(output, inputs);
+	}
+
+	/*
+		Add an Casting Table recipe.
+	*/
+	function addCastingTable(output as IItemStack, cast as IIngredient, fluid as ILiquidStack, amount as int) {
+		Casting.addTableRecipe(output, cast, fluid, amount);
+	}
+	function addCastingTable(output as IItemStack, cast as IIngredient, fluid as ILiquidStack, amount as int, consumeCast as bool) {
+		Casting.addTableRecipe(output, cast, fluid, amount, consumeCast);
+	}
+	function addCastingTable(output as IItemStack, cast as IIngredient, fluid as ILiquidStack, amount as int, consumeCast as bool, time as int) {
+		Casting.addTableRecipe(output, cast, fluid, amount, consumeCast, time);
+	}
+
+	/*
+		Remove an Casting Table recipe.
+	*/
+	function removeCastingTable(output as IItemStack) {
+		Casting.removeTableRecipe(output);
+	}
+
+	/*
+		Add an Casting Basin recipe.
+	*/
+	function addCastingBasin(output as IItemStack, cast as IIngredient, fluid as ILiquidStack, amount as int) {
+		Casting.addBasinRecipe(output, cast, fluid, amount);
+	}
+	function addCastingBasin(output as IItemStack, cast as IIngredient, fluid as ILiquidStack, amount as int, consumeCast as bool) {
+		Casting.addBasinRecipe(output, cast, fluid, amount, consumeCast);
+	}
+	function addCastingBasin(output as IItemStack, cast as IIngredient, fluid as ILiquidStack, amount as int, consumeCast as bool, time as int) {
+		Casting.addBasinRecipe(output, cast, fluid, amount, consumeCast, time);
+	}
+
+	/*
+		Remove an Casting Basin recipe.
+	*/
+	function removeCastingBasin(output as IItemStack) {
+		Casting.removeBasinRecipe(output);
+	}
+
+	/*
+		Add a Drying Recipe
+	*/
+	function addDrying(output as IItemStack, input as IIngredient, time as int) {
+		Drying.addRecipe(output, input, time);
+	}
+
+	/*
+		Remove a Drying Recipe.
+	*/
+	function removeDrying(output as IItemStack) {
+		Drying.removeRecipe(output);
+	}
+	function removeDrying(output as IItemStack, input as IItemStack) {
+		Drying.removeRecipe(output, input);
+	}
+
+	/*
+		Add a Melting Recipe.
+	*/
+	function addMelting(output as ILiquidStack, input as IIngredient) {
+		Melting.addRecipe(output, input);
+	}
+	function addMelting(output as ILiquidStack, input as IIngredient, time as int) {
+		Melting.addRecipe(output, input, time);
+	}
+	function addMeltingEntity(entity as IEntityDefinition, output as ILiquidStack) {
+		Melting.addEntityMelting(entity, output);
+	}
+
+	/*
+		Remove a Melting Recipe.
+	*/
+	function removeMelting(output as ILiquidStack) {
+		Melting.removeRecipe(output);
+	}
+	function removeMelting(output as ILiquidStack, input as IItemStack) {
+		Melting.removeRecipe(output, input);
+	}
+	function removeMeltingEntity(entity as IEntityDefinition) {
+		Melting.removeEntityMelting(entity);
+	}
+}