Bonchellon/sevtech-ages-1.12.2
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

minecraft server init

Browse Source
This commit is contained in:
Bonchellon
2025-07-23 08:37:00 +03:00
commit ccf1f5f4d0
2460 changed files with 291551 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

29
scripts/crafttweaker/integrations/mods/immersive/engineering/alloySmelter.zs Normal file
View File

@ -0,0 +1,29 @@
/*
SevTech: Ages Immersive Engineering Alloy Smelter Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
function init() {
// Black Iron Creation
immersiveEngineering.addAlloy(metals.blackIron.ingot.firstItem, <actuallyadditions:item_dust:7>, metals.iron.ingot);
// Invar must be in Arc Furnace
immersiveEngineering.removeAlloy(metals.invar.ingot.firstItem);
// Add bronze recipe
immersiveEngineering.removeAlloy(metals.bronze.ingot.firstItem);
immersiveEngineering.addAlloy(metals.bronze.ingot.firstItem * 4, metals.copper.ingot * 3, metals.tin.ingot);
immersiveEngineering.addAlloy(metals.bronze.ingot.firstItem * 4, metals.copper.ingot * 3, metals.tin.dust);
immersiveEngineering.addAlloy(metals.bronze.ingot.firstItem * 4, metals.copper.dust * 3, metals.tin.ingot);
immersiveEngineering.addAlloy(metals.bronze.ingot.firstItem * 4, metals.copper.dust * 3, metals.tin.dust);
// Invar
immersiveEngineering.addAlloy(metals.invar.ingot.firstItem * 3, metals.iron.ingot * 2, metals.nickel.ingot);
immersiveEngineering.addAlloy(metals.invar.ingot.firstItem * 3, metals.iron.ingot * 2, metals.nickel.dust);
immersiveEngineering.addAlloy(metals.invar.ingot.firstItem * 3, metals.iron.dust * 2, metals.nickel.ingot);
immersiveEngineering.addAlloy(metals.invar.ingot.firstItem * 3, metals.iron.dust * 2, metals.nickel.dust);
}

90
scripts/crafttweaker/integrations/mods/immersive/engineering/arcFurnace.zs Normal file
View File

@ -0,0 +1,90 @@
/*
SevTech: Ages Immersive Engineering Arc Furnace Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import crafttweaker.item.IItemStack;
function init() {
var slag as IItemStack = <ore:itemSlag>.firstItem;
// Quartz Glass
immersiveEngineering.addArcFurn(<appliedenergistics2:quartz_glass:0> * 4, <ore:blockGlass> * 4, null, 200, 512,
[<ore:dustQuartz> * 5]
);
// Vanilla Glass
immersiveEngineering.addArcFurn(<minecraft:glass:0>, <ore:sand>, null, 150, 256);
// Vanilla Glass Panes
immersiveEngineering.addArcFurn(<minecraft:glass_pane:0>, <betterwithmods:sand_pile:0> * 2, null, 100, 150);
//==============================================================
// Add Steve's carts recipes
// Lump of Galgador
immersiveEngineering.addArcFurn(<stevescarts:modulecomponents:46> * 2, metals.platinum.block.firstItem, slag, 200, 512,
[<minecraft:glowstone_dust:0> * 3, <stevescarts:modulecomponents:45> * 3, <stevescarts:modulecomponents:21> * 2]
);
//Stabilized Metal
immersiveEngineering.addArcFurn(<stevescarts:modulecomponents:21> * 5, <stevescarts:modulecomponents:20>, slag, 200, 512,
[metals.iron.ingot.firstItem * 5, <stevescarts:modulecomponents:19> * 3]
);
//==============================================================
// Add recipes for alloying that is removed by metals script
// Also adding slag as an output to them all
// Steel
immersiveEngineering.addArcFurn(metals.steel.ingot.firstItem, metals.iron.ingot, slag, 300, 448, [<ore:dustCoke>]);
// Constantan
immersiveEngineering.addArcFurn(metals.constantan.ingot.firstItem * 2, metals.copper.ingot, slag, 100, 512, [metals.nickel.dust]);
immersiveEngineering.addArcFurn(metals.constantan.ingot.firstItem * 2, metals.nickel.ingot, slag, 100, 512, [metals.copper.dust]);
// Electrum
immersiveEngineering.addArcFurn(metals.electrum.ingot.firstItem * 2, metals.gold.ingot, slag, 100, 512, [metals.silver.dust]);
immersiveEngineering.addArcFurn(metals.electrum.ingot.firstItem * 2, metals.silver.ingot, slag, 100, 512, [metals.gold.dust]);
// Invar
immersiveEngineering.addArcFurn(metals.invar.ingot.firstItem * 3, metals.nickel.ingot, slag, 100, 512, [metals.iron.dust * 2]);
// Ender Utilities
immersiveEngineering.addArcFurn(<enderutilities:enderpart:0> * 4, <minecraft:ender_pearl:0>, slag, 100, 512, [<quark:biotite:0> * 8]);
immersiveEngineering.addArcFurn(<enderutilities:enderpart:1> * 4, <minecraft:ender_eye:0>, slag, 100, 512, [<minecraft:chorus_fruit:0> * 8]);
immersiveEngineering.addArcFurn(<enderutilities:enderpart:2> * 2, <minecraft:ender_eye:0>, slag, 100, 512, [<minecraft:purpur_block:0> * 4, <minecraft:end_rod:0> * 2, <minecraft:shulker_shell:0>]);
immersiveEngineering.addArcFurn(<enderutilities:enderpart:20> * 4, <minecraft:ender_pearl:0>, slag, 100, 512, [<minecraft:end_rod:0> * 4]);
// Black Iron
immersiveEngineering.addArcFurn(<extendedcrafting:material:0>, metals.iron.ingot, slag, 100, 512, [<actuallyadditions:item_dust:7>]);
// Refined Energistics 2.3333333 <- YA! YOU LIKE THAT
immersiveEngineering.addArcFurn(<refinedstorage:quartz_enriched_iron:0> * 4, metals.iron.ingot * 3, slag, 100, 512, [<appliedenergistics2:material:0>]);
// Bronze Alloying
immersiveEngineering.addArcFurn(metals.bronze.ingot.firstItem * 4, metals.copper.ingot * 3, slag, 100, 512, [metals.tin.dust]);
// Redstone Alloy
immersiveEngineering.addArcFurn(metals.redstoneAlloy.ingot.firstItem * 2, metals.constantan.ingot, slag, 100, 512, [<minecraft:glowstone_dust:0>, <minecraft:redstone:0>]);
// Modularium
immersiveEngineering.addArcFurn(metals.modularium.ingot.firstItem * 2, metals.aluminum.ingot, slag, 100, 512, [metals.iron.dust, <minecraft:redstone:0>]);
immersiveEngineering.addArcFurn(metals.modularium.ingot.firstItem * 2, metals.iron.ingot, slag, 100, 512, [metals.aluminum.dust, <minecraft:redstone:0>]);
// Aluminum Brass
immersiveEngineering.addArcFurn(metals.aluminumBrass.ingot.firstItem * 4, metals.copper.ingot, slag, 100, 512, [metals.aluminum.dust * 3]);
// Manyullyn
immersiveEngineering.addArcFurn(metals.manyullyn.ingot.firstItem, metals.cobalt.ingot, slag, 300, 512, [metals.ardite.ingot]);
immersiveEngineering.addArcFurn(metals.manyullyn.ingot.firstItem, metals.ardite.ingot, slag, 300, 512, [metals.cobalt.ingot]);
// Add a few ore to ingot recipes for metals without dust
// Cobalt
immersiveEngineering.addArcFurn(metals.cobalt.ingot.firstItem * 2, metals.cobalt.ore, null, 600, 512);
// Ardite
immersiveEngineering.addArcFurn(metals.ardite.ingot.firstItem * 2, metals.ardite.ore, null, 200, 512);
}

14
scripts/crafttweaker/integrations/mods/immersive/engineering/bottlingMachine.zs Normal file
View File

@ -0,0 +1,14 @@
/*
SevTech: Ages Immersive Engineering Bottling Machine Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.immersiveengineering.BottlingMachine;
function init() {
BottlingMachine.addRecipe(<minecraft:potion:0>.withTag({Potion: "minecraft:water"}), <minecraft:glass_bottle:0>, <liquid:water> * 1000);
}

40
scripts/crafttweaker/integrations/mods/immersive/engineering/crusher.zs Normal file
View File

@ -0,0 +1,40 @@
/*
SevTech: Ages Immersive Engineering Crusher Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
function init() {
immersiveEngineering.removeCrusher(<actuallyadditions:item_dust:4>);
immersiveEngineering.addCrusher(<primal:tannin_ground:0> * 2, <ore:barkWood>, 3000); // Ground Resin from bark
immersiveEngineering.addCrusher(<betterwithmods:material:3> * 2, <betterwithmods:material:2>, 3000);
immersiveEngineering.addCrusher(<minecraft:dye:15> * 9, <minecraft:bone_block:0>, 3000);
immersiveEngineering.addCrusher(<minecraft:sugar:0> * 2, <minecraft:reeds:0>, 3000);
immersiveEngineering.addCrusher(<betterwithmods:material:15>, <ore:netherrack>, 3000); // Ground netherrack
immersiveEngineering.addCrusher(<appliedenergistics2:material:8>, <appliedenergistics2:material:7>, 3000); // Fluix dust can be made in immersiveEngineering
immersiveEngineering.addCrusher(metals.spacePlatinum.dust.firstItem * 2, <ore:oreSpacePlatinum>, 3000); // Osmium ore to dust
immersiveEngineering.addCrusher(<ore:dustCoal>.firstItem, <ore:coal>, 3000); // Coal to coal dust
immersiveEngineering.addCrusher(<appliedenergistics2:material:2>, <appliedenergistics2:material:0>, 3000); // Certus Quartz to Certus Dust
immersiveEngineering.addCrusher(<horsepower:flour:0>, <minecraft:wheat:0>, 3000); // Wheat to Flour
immersiveEngineering.addCrusher(<primal:bone_knapp:0>, <primal:sharp_bone:0>, 3000); // Sharp Bone to Bone Knapp
immersiveEngineering.addCrusher(<minecraft:dye:15> * 2, <primal:shark_tooth:0>, 3000); // Sharp Bone to Bone Knapp
immersiveEngineering.addCrusher(<primal:salt_dust_netjry:0> * 4, <primal:salt_netjry_block:0>, 3000); // Netjry Salt to Netjry Salt
immersiveEngineering.addCrusher(<primal:salt_dust_rock:0> * 4, <primal:ore_salt:0>, 3000); // Halite Salt Ore to Halite Rock Salt
immersiveEngineering.addCrusher(<primal:salt_dust_fire:0> * 4, <primal:ore_salt:1>, 3000); // Fire Salt Ore to Fire Rock Salt
immersiveEngineering.addCrusher(<betterwithmods:material:37>, <minecraft:coal:1>, 3000); // Charcoal to Dust
immersiveEngineering.addCrusher(<ore:dustSalt>.firstItem * 4, <mekanism:saltblock:0>, 3000); // Salt Block -> Dust
immersiveEngineering.addCrusher(<minecraft:diamond:0> * 9, <minecraft:diamond_block:0>, 3000); // Diamond Block -> Diamonds
immersiveEngineering.addCrusher(<minecraft:dye:4> * 9, <minecraft:lapis_block:0>, 3000); // Lapis Block -> Lapis
immersiveEngineering.addCrusher(<minecraft:redstone:0> * 9, <minecraft:redstone_block:0>, 3000); // Redstone Block -> Redstone
immersiveEngineering.addCrusher(<minecraft:emerald:0> * 9, <minecraft:emerald_block:0>, 3000); // Emerald Block -> Emerald
immersiveEngineering.addCrusher(<minecraft:dye:15> * 3, <death_compass:death_compass>.withTag({}), 3000); // Death Compass -> Bone Meal
// Remove wool -> minecraft dye and string.
immersiveEngineering.removeCrusher(<minecraft:string:0>);
immersiveEngineering.removeCrusher(<primal:quartz_vitrified:0>);
}

133
scripts/crafttweaker/integrations/mods/immersive/engineering/excavator.zs Normal file
View File

@ -0,0 +1,133 @@
/*
SevTech: Ages Immersive Engineering Excavator Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.immersiveengineering.Excavator;
import mods.immersiveengineering.MineralMix;
function init() {
// Remove Minerals
Excavator.removeMineral("Bauxite");
Excavator.removeMineral("Cinnabar");
Excavator.removeMineral("Coal");
Excavator.removeMineral("Copper");
Excavator.removeMineral("Galena");
Excavator.removeMineral("Gold");
Excavator.removeMineral("Iron");
Excavator.removeMineral("Lapis");
Excavator.removeMineral("Lead");
Excavator.removeMineral("Magnetite");
Excavator.removeMineral("Nickel");
Excavator.removeMineral("Pyrite");
Excavator.removeMineral("Quartzite");
Excavator.removeMineral("Silver");
Excavator.removeMineral("Uranium");
// Black Quartzite
Excavator.addMineral("Black Quartzite", 30, 0.15, [], [], [10], false);
var blackQuartzite = Excavator.getMineral("Black Quartzite");
blackQuartzite.addOre("gemQuartzBlack", 0.50);
// Nether Quartzite
Excavator.addMineral("Nether Quartzite", 30, 0.15, [], [], [-1], true);
var netherQuartzite = Excavator.getMineral("Nether Quartzite");
netherQuartzite.addOre("gemQuartz", 0.50);
// Certus Quartzite
Excavator.addMineral("Certus Quartzite", 30, 0.15, [], [], [-1], true);
var certusQuartzite = Excavator.getMineral("Certus Quartzite");
certusQuartzite.addOre("crystalCertusQuartz", 0.70);
certusQuartzite.addOre("crystalCertusQuartzCharged", 0.30);
// Autunite (Uranium)
Excavator.addMineral("Autunite", 30, 0.15, [], [], [-1], true);
var autunite = Excavator.getMineral("Autunite");
autunite.addOre("oreClusterUranium", 0.50);
// Azurite (Copper)
Excavator.addMineral("Azurite", 30, 0.15, [], [], [-1], true);
var azurite = Excavator.getMineral("Azurite");
azurite.addOre("oreClusterCopper", 0.50);
// Bauxite (Aluminum)
Excavator.addMineral("Bauxite", 30, 0.15, [], [], [-1], true);
var bauxite = Excavator.getMineral("Bauxite");
bauxite.addOre("oreClusterAluminum", 0.50);
// Beryl (Emerald)
Excavator.addMineral("Beryl", 5, 0.45, [], [], [-1], true);
var beryl = Excavator.getMineral("Beryl");
beryl.addOre("gemEmerald", 0.50);
// Cassiterite (Tin)
Excavator.addMineral("Cassiterite", 30, 0.15, [], [], [-1], true);
var cassiterite = Excavator.getMineral("Cassiterite");
cassiterite.addOre("oreClusterTin", 0.50);
// Cinnabar (Redstone)
Excavator.addMineral("Cinnabar", 30, 0.15, [], [], [-1], true);
var cinnabar = Excavator.getMineral("Cinnabar");
cinnabar.addOre("dustRedstone", 0.50);
// Coal
Excavator.addMineral("Coal", 30, 0.15, [], [], [-1], true);
var coal = Excavator.getMineral("Coal");
coal.addOre("coal", 0.50);
// Galena (Silver and Lead)
Excavator.addMineral("Galena", 30, 0.15, [], [], [-1], true);
var galena = Excavator.getMineral("Galena");
galena.addOre("oreClusterSilver", 0.70);
galena.addOre("oreClusterLead", 0.30);
// Gold
Excavator.addMineral("Gold", 30, 0.15, [], [], [-1], true);
var gold = Excavator.getMineral("Gold");
gold.addOre("oreClusterGold", 0.50);
// Hematite (Iron)
Excavator.addMineral("Hematite", 30, 0.15, [], [], [-1], true);
var hematite = Excavator.getMineral("Hematite");
hematite.addOre("oreClusterIron", 0.50);
// Kimberlight (Diamond)
Excavator.addMineral("Kimberlight", 5, 0.45, [], [], [-1], true);
var kimberlight = Excavator.getMineral("Kimberlight");
kimberlight.addOre("gemDiamond", 0.50);
// Lapis
Excavator.addMineral("Lapis", 30, 0.15, [], [], [-1], true);
var lapis = Excavator.getMineral("Lapis");
lapis.addOre("gemLapis", 0.50);
// Limonite (Iron and Nickel)
Excavator.addMineral("Limonite", 30, 0.15, [], [], [-1], true);
var limonite = Excavator.getMineral("Limonite");
limonite.addOre("oreClusterIron", 0.70);
limonite.addOre("oreClusterNickel", 0.30);
// Malachite (Copper)
Excavator.addMineral("Malachite", 30, 0.15, [], [], [-1], true);
var malachite = Excavator.getMineral("Malachite");
malachite.addOre("oreClusterCopper", 0.50);
// Platinum
Excavator.addMineral("Platinum", 30, 0.15, [], [], [-1], true);
var platinum = Excavator.getMineral("Platinum");
platinum.addOre("oreClusterPlatinum", 0.50);
// Osmium
Excavator.addMineral("Osmium", 30, 0.15, [], [], [-1], true);
var osmium = Excavator.getMineral("Osmium");
osmium.addOre("oreClusterOsmium", 0.50);
// Teallite (Tin)
Excavator.addMineral("Teallite", 30, 0.15, [], [], [-1], true);
var teallite = Excavator.getMineral("Teallite");
teallite.addOre("oreClusterTin", 0.50);
}

22
scripts/crafttweaker/integrations/mods/immersive/engineering/init.zs Normal file
View File

@ -0,0 +1,22 @@
#priority -50
/*
SevTech: Ages Immersive Engineering Loader Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
function init() {
scripts.crafttweaker.integrations.mods.immersive.engineering.alloySmelter.init();
scripts.crafttweaker.integrations.mods.immersive.engineering.arcFurnace.init();
scripts.crafttweaker.integrations.mods.immersive.engineering.bottlingMachine.init();
scripts.crafttweaker.integrations.mods.immersive.engineering.crusher.init();
scripts.crafttweaker.integrations.mods.immersive.engineering.excavator.init();
scripts.crafttweaker.integrations.mods.immersive.engineering.metalPress.init();
scripts.crafttweaker.integrations.mods.immersive.engineering.mixer.init();
scripts.crafttweaker.integrations.mods.immersive.engineering.refinery.init();
scripts.crafttweaker.integrations.mods.immersive.engineering.squeezer.init();
}

55
scripts/crafttweaker/integrations/mods/immersive/engineering/metalPress.zs Normal file
View File

@ -0,0 +1,55 @@
/*
SevTech: Ages Immersive Engineering Metal Press Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
function init() {
immersiveEngineering.addPress(<minecraft:blaze_rod:0>, <minecraft:blaze_powder:0>, <immersiveengineering:mold:2>, 4);
immersiveEngineering.addPress(metals.compressedIron.ingot.firstItem * 4, metals.iron.block.firstItem, <immersiveengineering:mold:5>, 2000, 1);
immersiveEngineering.addPress(<pickletweaks:ppm4:2> * 4, <galacticraftcore:item_basic_moon:0>, <immersiveengineering:mold:4>, 1);
// Coal and Charcoal Blocks / Pieces
immersiveEngineering.addPress(<minecraft:coal_block:0> * 1, <minecraft:coal:0>, <immersiveengineering:mold:6>, 9);
immersiveEngineering.addPress(<charcoalblock:charcoal_block:0> * 1, <minecraft:coal:1>, <immersiveengineering:mold:6>, 9);
immersiveEngineering.addPress(<minecraft:coal:0> * 9, <minecraft:coal_block:0>, <immersiveengineering:mold:7>, 1);
immersiveEngineering.addPress(<minecraft:coal:1> * 9, <charcoalblock:charcoal_block:0>, <immersiveengineering:mold:7>, 1);
// Clay Balls -> Clay Block
immersiveEngineering.addPress(<minecraft:clay:0> * 1, <minecraft:clay_ball:0>, <immersiveengineering:mold:5>, 4);
immersiveEngineering.addPress(<minecraft:clay_ball:0> * 4, <minecraft:clay:0>, <immersiveengineering:mold:7>, 1);
// Shadowfragment -> Shadowshard
immersiveEngineering.addPress(<abyssalcraft:shadowshard:0> * 1, <abyssalcraft:shadowfragment:0>, <immersiveengineering:mold:6>, 9);
// Shadowshard -> Shadowgem
immersiveEngineering.addPress(<abyssalcraft:shadowgem:0> * 1, <abyssalcraft:shadowshard:0>, <immersiveengineering:mold:6>, 9);
// Shadowshard -> Shadowfragment
immersiveEngineering.addPress(<abyssalcraft:shadowfragment:0> * 9, <abyssalcraft:shadowshard:0>, <immersiveengineering:mold:7>, 1);
// Shadowgem -> Shadowshard
immersiveEngineering.addPress(<abyssalcraft:shadowshard:0> * 9, <abyssalcraft:shadowgem:0>, <immersiveengineering:mold:7>, 1);
// Salt Dust -> Salt Block
immersiveEngineering.addPress(<primal:salt_netjry_block:0> * 1, <primal:salt_dust_netjry:0>, <immersiveengineering:mold:5>, 4);
immersiveEngineering.addPress(<primal:ore_salt:1> * 1, <primal:salt_dust_fire:0>, <immersiveengineering:mold:5>, 4);
immersiveEngineering.addPress(<primal:ore_salt:0> * 1, <primal:salt_dust_rock:0>, <immersiveengineering:mold:5>, 4);
immersiveEngineering.addPress(<mekanism:saltblock:0> * 1, <mekanism:salt:0>, <immersiveengineering:mold:5>, 4);
// Diamond Block
immersiveEngineering.addPress(<minecraft:diamond_block:0> * 1, <minecraft:diamond:0>, <immersiveengineering:mold:6>, 9);
immersiveEngineering.addPress(<minecraft:diamond:0> * 9, <minecraft:diamond_block:0>, <immersiveengineering:mold:7>, 1);
// Lapis Block
immersiveEngineering.addPress(<minecraft:lapis_block:0> * 1, <minecraft:dye:4>, <immersiveengineering:mold:6>, 9);
immersiveEngineering.addPress(<minecraft:dye:4> * 9, <minecraft:lapis_block:0>, <immersiveengineering:mold:7>, 1);
// Redstone Block
immersiveEngineering.addPress(<minecraft:redstone_block:0> * 1, <minecraft:redstone:0>, <immersiveengineering:mold:6>, 9);
immersiveEngineering.addPress(<minecraft:redstone:0> * 9, <minecraft:redstone_block:0>, <immersiveengineering:mold:7>, 1);
// Emerald Block
immersiveEngineering.addPress(<minecraft:emerald_block:0> * 1, <minecraft:emerald:0>, <immersiveengineering:mold:6>, 9);
immersiveEngineering.addPress(<minecraft:emerald:0> * 9, <minecraft:emerald_block:0>, <immersiveengineering:mold:7>, 1);
}

16
scripts/crafttweaker/integrations/mods/immersive/engineering/mixer.zs Normal file
View File

@ -0,0 +1,16 @@
/*
SevTech: Ages Immersive Engineering Mixer Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.immersiveengineering.Mixer;
function init() {
Mixer.addRecipe(<liquid:slime> * 500, <liquid:water> * 500, [<minecraft:wheat:0>, <minecraft:clay_ball:0>], 50);
Mixer.addRecipe(<liquid:blueslime> * 500, <liquid:slime> * 500, [<pickletweaks:dye_powder:11>, <natura:nether_glowshroom:1>], 50);
Mixer.addRecipe(<liquid:purpleslime> * 500, <liquid:slime> * 500, [<pickletweaks:dye_powder:10>, <nex:amethyst_crystal:0>], 50);
}

15
scripts/crafttweaker/integrations/mods/immersive/engineering/refinery.zs Normal file
View File

@ -0,0 +1,15 @@
/*
SevTech: Ages Immersive Engineering Refinery Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.immersiveengineering.Refinery;
function init() {
Refinery.addRecipe(<liquid:fuel> * 100, <liquid:liquidoxygen> * 250, <liquid:kerosene> * 100, 2048);
Refinery.addRecipe(<liquid:fuel> * 100, <liquid:oxygen> * 250, <liquid:kerosene> * 100, 2048);
}

22
scripts/crafttweaker/integrations/mods/immersive/engineering/squeezer.zs Normal file
View File

@ -0,0 +1,22 @@
/*
SevTech: Ages Immersive Engineering Squeezer Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.immersiveengineering.Squeezer;
function init() {
Squeezer.removeItemRecipe(<minecraft:leather:0>); // Remove Rotten Flesh -> Leather
// Rustic recipes to make people "jump less" Kappa. Thanks to @iffonox!
Squeezer.addRecipe(null, <liquid:wildberryjuice> * 250, <rustic:wildberries>, 2048);
Squeezer.addRecipe(null, <liquid:oliveoil> * 250, <rustic:olives>, 2048);
Squeezer.addRecipe(null, <liquid:honey> * 250, <rustic:honeycomb>, 2048);
Squeezer.addRecipe(null, <liquid:grapejuice> * 250, <rustic:grapes>, 2048);
Squeezer.addRecipe(null, <liquid:applejuice> * 250, <minecraft:apple>, 2048);
Squeezer.addRecipe(<minecraft:sugar> * 2, <liquid:water> * 250, <minecraft:reeds>, 2048);
}

48
scripts/crafttweaker/integrations/mods/immersive/petroleum.zs Normal file
View File

@ -0,0 +1,48 @@
/*
SevTech: Ages Immersive Petroleum Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import mods.immersivepetroleum.Distillation;
import mods.immersivepetroleum.Motorboat;
import mods.immersivepetroleum.PortableGenerator;
import mods.immersivepetroleum.Reservoir;
/*
Support:
Distillation: http://crafttweaker.readthedocs.io/en/latest/#Mods/Immersive_Petroleum/CraftTweaker_Support/Distillation/
Reservoir: http://crafttweaker.readthedocs.io/en/latest/#Mods/Immersive_Petroleum/CraftTweaker_Support/Reservoir/
Fuel Registration: http://crafttweaker.readthedocs.io/en/latest/#Mods/Immersive_Petroleum/CraftTweaker_Support/FuelRegistration/
*/
function init() {
// Distillation
Distillation.addRecipe(
[<liquid:diesel> * 50, <liquid:naphtha> * 50],
[<immersivepetroleum:material:0>],
<liquid:oil> * 100,
2048, 1,
[0.07]
);
Distillation.addRecipe(
[<liquid:lubricant> * 20, <liquid:gasoline> * 40, <liquid:kerosene> * 40],
[<immersivepetroleum:material:0>],
<liquid:diesel> * 100,
2048, 1,
[0.07]
);
// Reservoir
Reservoir.registerReservoir("aquifer", <liquid:water>, 5000000, 10000000, 6, 30, [], [0], [], []);
Reservoir.registerReservoir("oil", <liquid:oil>, 2500000, 15000000, 6, 40, [1], [], [], []);
Reservoir.registerReservoir("lava", <liquid:lava>, 250000, 1000000, 0, 30, [1], [], [], []);
// Fuel Registration
Motorboat.registerMotorboatFuel(<liquid:gasoline>, 1);
PortableGenerator.registerPortableGenFuel(<liquid:gasoline>, 256, 5);
}