Bonchellon/sevtech-ages-1.12.2
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

minecraft server init

Browse Source
This commit is contained in:
Bonchellon
2025-07-23 08:37:00 +03:00
commit ccf1f5f4d0
2460 changed files with 291551 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

28
scripts/crafttweaker/integrations/mods/tinkers/alloy.zs Normal file
View File

@ -0,0 +1,28 @@
/*
SevTech: Ages Tinkers Alloy Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
/*
Alloying
http://crafttweaker.readthedocs.io/en/latest/#Mods/Modtweaker/TConstruct/Alloying/
*/
function init() {
// Remove Constantan Alloying
tinkers.removeAlloying(metalItems.constantan.liquid.liquids[0]);
// Redstone Alloy Creation
tinkers.addAlloying(metalItems.redstoneAlloy.liquid.liquids[0] * 288, [<liquid:redstone> * 100, <liquid:glowstone> * 100, metalItems.constantan.liquid.liquids[0] * 144]);
// Modularium
tinkers.addAlloying(metalItems.modularium.liquid.liquids[0] * 288, [<liquid:redstone> * 100, metalItems.iron.liquid.liquids[0] * 144, metalItems.aluminum.liquid.liquids[0] * 144]);
// Invar
tinkers.addAlloying(metalItems.invar.liquid.liquids[0] * 3, [metalItems.iron.liquid.liquids[0] * 2, metalItems.nickel.liquid.liquids[0] * 1]);
}

124
scripts/crafttweaker/integrations/mods/tinkers/casting.zs Normal file
View File

@ -0,0 +1,124 @@
/*
SevTech: Ages Tinkers Casting Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
import crafttweaker.item.IItemDefinition;
import crafttweaker.item.IItemStack;
import crafttweaker.liquid.ILiquidStack;
/*
Casting
http://crafttweaker.readthedocs.io/en/latest/#Mods/Modtweaker/TConstruct/Casting/
*/
function init() {
/*
Cast Creation
*/
// [IItemStack cast, IItemStack consumedItem]
var castCreationRecipes as IItemStack[][] = [
[<tconstruct:cast_custom:2>, <astralsorcery:itemcraftingcomponent:0>], // Gem cast with Astral Sorcery Aquamarine
// Gear Cast Allows Stone now. You're welcome. -________________- Oh, it's also made from stone so all the people don't get upset with me and call me names or tell me I don't know rocket surgery.
[<tconstruct:cast_custom:4>, <teslacorelib:gear_stone:0>],
[<tconstruct:cast_custom:1>, <materialpart:stone:nugget>]
];
var castLiquids as ILiquidStack[] = [
metalItems.gold.liquid.liquids[0],
<liquid:brass>,
metalItems.aluminumBrass.liquid.liquids[0]
];
for castCreationRecipe in castCreationRecipes {
for castLiquid in castLiquids {
var liquidAmount = 144;
if (castLiquid.matches(metalItems.gold.liquid.liquids[0])) {
liquidAmount = 288;
}
tinkers.addCastingTable(castCreationRecipe[0], castCreationRecipe[1], castLiquid, liquidAmount, true);
}
}
/*
Spartan Shields
As long as the metal is in the metals global stuff, this will work without any modifications
*/
var shieldMetals as string[] = [
"bronze",
"constantan",
"steel",
"copper",
"tin",
"silver",
"platinum",
"electrum",
"nickel",
"iron",
"gold",
"obsidian",
"lead",
"invar"
];
for shieldMetal in shieldMetals {
var shield as IItemStack = itemUtils.getItem("spartanshields:shield_basic_" + shieldMetal);
var towerShield as IItemStack = itemUtils.getItem("spartanshields:shield_tower_" + shieldMetal);
var liquid as ILiquidStack = shieldMetal == "obsidian" ? <liquid:obsidian> : metalItems[shieldMetal].liquid.liquids[0];
tinkers.addCastingTable(shield, <spartanshields:shield_basic_wood:0> | <spartanshields:shield_basic_stone:0>, liquid, 576, true);
// tinkers.addCastingBasin(towerShield, <spartanshields:shield_tower_wood:0> | <spartanshields:shield_tower_stone:0>, liquid, 576, true); // TODO: Enable if model issue resolved
}
/*
Standard Casting
*/
tinkers.removeCastingTable(<minecraft:glass_pane:0>);
tinkers.addCastingTable(<minecraft:glass_pane:0>, null, <liquid:glass>, 500);
tinkers.removeCastingBasin(<tconstruct:clear_glass:0>);
tinkers.addCastingBasin(<minecraft:glass:0>, null, <liquid:glass>, 1000);
tinkers.addCastingTable(<minecraft:ender_pearl:0>, <tconstruct:cast:0>.withTag({PartType: "tconstruct:pan_head"}), <liquid:ender_pearl>, 250, false);
tinkers.addCastingBasin(<betterwithmods:aesthetic:8>, null, <liquid:ender_pearl>, 2250);
tinkers.addCastingTable(metals.steeleaf.rod.firstItem, <tconstruct:cast:0>.withTag({PartType: "tconstruct:tool_rod"}), metalItems.steeleaf.liquid.liquids[0], 144, false);
// Redstone Alloy Rod
// TODO: Is this being handled by metals?
tinkers.addCastingTable(metals.redstoneAlloy.rod.firstItem, <tconstruct:cast:0>.withTag({PartType: "tconstruct:tool_rod"}), metalItems.redstoneAlloy.liquid.liquids[0], 144, false);
// Nugget Removal
tinkers.removeCastingTable(<mysticalagriculture:crafting:45>); // Soulium Nugget
// Iron Chests
tinkers.addCastingBasin(<ironchest:iron_chest:0>, <ironchest:iron_chest:7>, metalItems.iron.liquid.liquids[0], 1152, true, 300);
tinkers.addCastingBasin(<ironchest:iron_chest:1>, <ironchest:iron_chest:7>, metalItems.gold.liquid.liquids[0], 1152, true, 300);
tinkers.addCastingBasin(<ironchest:iron_chest:3>, <ironchest:iron_chest:7>, metalItems.copper.liquid.liquids[0], 1152, true, 300);
tinkers.addCastingBasin(<ironchest:iron_chest:4>, <ironchest:iron_chest:7>, metalItems.silver.liquid.liquids[0], 1152, true, 300);
tinkers.addCastingBasin(<ironchest:iron_chest:6>, <ironchest:iron_chest:7>, <liquid:obsidian>, 1152, true, 300);
tinkers.addCastingBasin(<ironchest:iron_chest:5>, <ironchest:iron_chest:1>, <liquid:astralsorcery.liquidstarlight>, 1152, true, 300);
// Slime Ball Casting
tinkers.addCastingTable(<tconstruct:edible:2>, null, <liquid:purpleslime>, 250, false, 40);
tinkers.addCastingTable(<tconstruct:edible:1>, null, <liquid:blueslime>, 250, false, 40);
tinkers.addCastingTable(<minecraft:slime_ball:0>, null, <liquid:slime>, 250, false, 40);
tinkers.addCastingBasin(<tconstruct:slime_congealed:3>, null, <liquid:blood>, 640, false, 60);
tinkers.removeCastingBasin(<tconstruct:seared_furnace_controller:0>);
// Liquid Redstone
tinkers.addCastingTable(<minecraft:redstone:0>, <tconstruct:cast_custom:2>, <liquid:redstone>, 100, false);
tinkers.addCastingBasin(<minecraft:redstone_block:0>, null, <liquid:redstone>, 900);
// Liquid Glowstone
tinkers.addCastingTable(<minecraft:glowstone_dust:0>, <tconstruct:cast_custom:2>, <liquid:glowstone>, 100, false);
tinkers.addCastingBasin(<minecraft:glowstone:0>, null, <liquid:glowstone>, 400);
}

24
scripts/crafttweaker/integrations/mods/tinkers/dryingRack.zs Normal file
View File

@ -0,0 +1,24 @@
/*
SevTech: Ages Tinkers Drying Rack Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
function init() {
// Paper Creation
tinkers.addDrying(<betterwithaddons:japanmat:9>, <betterwithaddons:japanmat:8>, 2400);
tinkers.addDrying(<minecraft:paper:0>, <primal:plant_fiber_pulp:0>, 2400);
// Dried Fish
tinkers.addDrying(<primal:fish_salmon_dried:0>, <minecraft:fish:1>, 1600);
tinkers.addDrying(<primal:shark_meat_dried:0>, <primal:shark_meat_raw:0>, 1600);
// Leather Recipes
tinkers.removeDrying(<minecraft:leather:0>);
tinkers.addDrying(<minecraft:leather:0>, <primal:hide_tanned:0>, 2400);
tinkers.addDrying(<primal:hide_dried:0>, <primal:hide_salted:0>, 2400);
}

17
scripts/crafttweaker/integrations/mods/tinkers/init.zs Normal file
View File

@ -0,0 +1,17 @@
#priority -50
/*
SevTech: Ages Tinkers Loader Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
function init() {
scripts.crafttweaker.integrations.mods.tinkers.alloy.init();
scripts.crafttweaker.integrations.mods.tinkers.casting.init();
scripts.crafttweaker.integrations.mods.tinkers.dryingRack.init();
scripts.crafttweaker.integrations.mods.tinkers.melting.init();
}

73
scripts/crafttweaker/integrations/mods/tinkers/melting.zs Normal file
View File

@ -0,0 +1,73 @@
/*
SevTech: Ages Tinkers Melting Script
This script handles custom integration control to a mod.
Note: These scripts are created and for the usage in SevTech: Ages and other
modpacks curated by DarkPacks. You can use these scripts for reference and for
learning but not for copying and pasting and claiming as your own.
*/
/*
Melting
http://crafttweaker.readthedocs.io/en/latest/#Mods/Modtweaker/TConstruct/Melting/
*/
function init() {
tinkers.addMelting(<liquid:ender_pearl> * 250, <appliedenergistics2:material:46>);
// Platinum Ore
//TODO: Loop over oredict instead (and ensure ore is unified)
tinkers.addMelting(metalItems.platinum.liquid.liquids[0] * 144, <geolosys:cluster:8>);
// New seared stone mechanic
tinkers.removeMelting(<liquid:stone>);
tinkers.addMelting(<liquid:stone> * 72, <tconstruct:soil:0>);
tinkers.addMelting(<liquid:stone> * 72, <tconstruct:materials:0>);
var searedBlock = <tconstruct:seared:0>.definition;
for i in 0 .. 10{
if (i != 1){
tinkers.addMelting(<liquid:stone> * 288, searedBlock.makeStack(i));
}
}
tinkers.addMelting(<liquid:stone> * 216, <tconstruct:seared:1>);
// Steves Carts' Metals
tinkers.addMelting(metalItems.enhancedGalgadorian.liquid.liquids[0] * 144, <stevescarts:modulecomponents:48>);
tinkers.addMelting(metalItems.galgadorian.liquid.liquids[0] * 144, <stevescarts:modulecomponents:46>);
tinkers.addMelting(metalItems.reinforcedMetal.liquid.liquids[0] * 144, <stevescarts:modulecomponents:21>);
/*
Fixes so all glass is same melting temp.
I'm doing this against my better judgement because I don't want to hear players complaining about how it's impossible to make glass in stage 2 even though it's 100% possible already.
*/
tinkers.removeMelting(<liquid:glass>);
tinkers.addMelting(<liquid:glass> * 250, <ore:pileSand>, 493);
tinkers.addMelting(<liquid:glass> * 250, <ore:shardGlass>, 493);
tinkers.addMelting(<liquid:glass> * 375, <ore:paneGlass>, 493);
tinkers.addMelting(<liquid:glass> * 1000, <ore:blockGlass>, 493);
tinkers.addMelting(<liquid:glass> * 1000, <ore:sand>, 493);
// Remove Villager from giving emeralds or blood
tinkers.addMeltingEntity(<entity:minecraft:villager>, <liquid:water> * 0); // Setting to 0 gives nothing when the entity is "melted"
// Stops an exploit by removing the merchants melting.
tinkers.addMeltingEntity(<entity:farmingforblockheads:merchant>, <liquid:water> * 0); // Setting to 0 gives nothing when the entity is "melted"
/*
Combined stuff
*/
// Liquid Glowstone
tinkers.addMelting(<liquid:glowstone> * 100, <minecraft:glowstone_dust:0>);
tinkers.addMelting(<liquid:glowstone> * 400, <minecraft:glowstone:0>);
// Liquid Redstone
tinkers.addMelting(<liquid:redstone> * 100, <minecraft:redstone:0>);
tinkers.addMelting(<liquid:redstone> * 900, <minecraft:redstone_block:0>);
// Cheese
tinkers.addMelting(<liquid:cheese> * 100, <galacticraftcore:cheese:0>);
tinkers.addMelting(<liquid:cheese> * 10, <galacticraftcore:cheese_curd:0>);
}