minecraft server init

scripts/crafttweaker/recipes/mods/ironjetpacks.zs

@@ -0,0 +1,84 @@
+/*
+    SevTech: Ages Iron Jetpacks Recipe Script
+
+    This script handles the recipes for Iron Jetpacks.
+
+    Note: These scripts are created and for the usage in SevTech: Ages and other
+    modpacks curated by DarkPacks. You can use these scripts for reference and for
+    learning but not for copying and pasting and claiming as your own.
+*/
+import crafttweaker.item.IItemStack;
+import crafttweaker.item.IIngredient;
+
+/*
+    Shaped Recipes
+*/
+static shapedRecipes as IIngredient[][][][IItemStack] = {
+	<ironjetpacks:electrum_capacitor:0>: [
+		[
+			[<galacticraftcore:basic_item:9>, <ironjetpacks:electrum_cell:0>, <galacticraftcore:basic_item:9>],
+			[metals.electrum.plate, <ironjetpacks:electrum_cell:0>, metals.electrum.plate],
+			[<mekanism:compressedobsidian:0>, metals.compressedIron.gear, <mekanism:compressedobsidian:0>]
+		]
+	],
+	<ironjetpacks:basic_coil:0>: [
+		[
+			[null, <immersiveengineering:wirecoil:1>, metals.redstoneAlloy.rod],
+			[<immersiveengineering:wirecoil:5>, metals.redstoneAlloy.rod, <immersiveengineering:wirecoil:5>],
+			[metals.redstoneAlloy.rod, <immersiveengineering:wirecoil:1>, null]
+		]
+	],
+	<ironjetpacks:advanced_coil:0>: [
+		[
+			[null, <immersiveengineering:wirecoil:4>, metals.galgadorian.rod],
+			[<immersiveengineering:wirecoil:5>, metals.galgadorian.rod, <immersiveengineering:wirecoil:5>],
+			[metals.galgadorian.rod, <immersiveengineering:wirecoil:4>, null]
+		]
+	]
+};
+
+static namedShapedRecipes as IIngredient[][][][string][IItemStack] = {};
+
+/*
+    Mirrored Recipes
+*/
+static mirroredRecipes as IIngredient[][][][IItemStack] = {};
+
+static namedMirroredRecipes as IIngredient[][][][string][IItemStack] = {};
+
+/*
+    Shapeless Recipes
+*/
+static shapelessRecipes as IIngredient[][][IItemStack] = {};
+
+static namedShapelessRecipes as IIngredient[][][string][IItemStack] = {};
+
+/*
+    Recipe Removals
+*/
+static removeRecipes as IItemStack[] = [
+	<ironjetpacks:advanced_coil:0>,
+	<ironjetpacks:basic_coil:0>,
+	<ironjetpacks:electrum_capacitor:0>
+];
+
+static hiddenRemove as IIngredient[] = [
+	<ironjetpacks:elite_coil>,
+	<ironjetpacks:ultimate_coil>
+];
+
+function init() {
+	// Un-named recipes
+	recipeUtil.process(shapedRecipes, false);
+    recipeUtil.process(mirroredRecipes, true);
+    recipeUtil.process(shapelessRecipes);
+
+	// Named recipes
+	recipeUtil.processNamed(namedShapedRecipes, false);
+    recipeUtil.processNamed(namedMirroredRecipes, true);
+    recipeUtil.processNamed(namedShapelessRecipes);
+
+	recipeUtil.removeRecipes(removeRecipes);
+
+	recipeUtil.hideItems(hiddenRemove as IIngredient[], true);
+}